﻿title   CP/M V2.2 Double Density boot for Zobex controller (13-Jun-81)
;########################################################;
;#                                                      #;
;#        Zobex DD-FDC Double Density CP/M boot         #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#   Written by: Frank MacLachlan                       #;
;#   Date:       13-Mar-81                              #;
;#   Last rev:   13-Jun-81                              #;
;#                                                      #;
;########################################################;


FALSE   equ     0
TRUE    equ     not FALSE


MSIZE   equ     63              ; CP/M system size in decimal kbytes
CPMTOP  equ     MSIZE*1024      ; size of CP/M system in bytes
BIAS    equ     (MSIZE-20)*1024 ; bias for systems greater than 20k
CCP     equ     3400h+BIAS      ; base of CCP
BDOS    equ     CCP+806h        ; base of CP/M BDOS
CBIOS   equ     CCP+1600h       ; base of CP/M CBIOS
BOOTE   equ     CBIOS           ; CBIOS cold boot entry point
BUFF    equ     80h             ; default dma buffer adr
TBASE   equ     100h            ; base adr of transient pgm area


TRYS    equ     10              ; number of retries for read/write errors
RATE    equ     10b             ; step rate = 10 msec for slow poke drives
FDBASE  equ     90h             ; base of I/O ports for FD controller
OSTRKS  equ     1               ; number of tracks reserved for os
MINSEC  equ     0               ; minimum sector number for DD 8" disks
MAXSEC  equ     15              ; maximum sector number for DD 8" disks
SECLEN  equ     512             ; number of bytes per sector


;       Library definitions:


        list    off
*include zsiodfs.z80
*include 179Xdfs.z80
*include zdmadfs.z80
*include zdddfs.z80
        list    on


;       Macro definitions:


tsta    macro                   ;; set accum flags
        or      a,a
        endm


clra    macro                   ;; A := 0
        xor     a,a
        endm


clrcf   macro                   ;; CY := 0
        or      a,a
        endm




        org     0080h


boot:   di
        ld      a,01h
        out     (BNKSEL),a      ; select bank 0
        out     (PROMDB),a      ; disable prom
        ld      sp,boot         ; set stack below program
        ld      a,0<<BFRENB|1<<MTRON|0<<SIDE1|0<<SDEN|1<<SELENB|0
        out     (FDXCSR),a      ; select drive 0, double density, side 0
        ld      a,HOMCMD or LODHD or VERIFY or RATE
        out     (FDCSR),a       ; issue restore cmd
        call    bsywat          ; wait til done
        ld      hl,CCP-128      ; first adr to load
        ld      de,[MINSEC]<<8|RDCMD    ; D := first sector, E := read cmd
bot0:   ld      a,d
        out     (FDSEC),a       ; set sector adr
        ld      c,FDDAT         ; C := FDC data port adr
        ld      a,e             ; A := read cmd
        out     (FDCSR),a       ; issue read cmd
        jr      bot4            ;   and enter read loop
        ;
bot2:   ini                     ; input next data byte
bot4:   in      a,(FDSYNC)      ; wait for IRQ/DRQ
        rra
        jr      nc,bot2         ; repeat until IRQ
        in      a,(FDCSR)       ; read controller status
        and     a,RDMSK         ; isolate error bits
        jr      nz,bot0         ; start all over if error
        inc     d               ; sector := sector + 1
        ld      a,d
        cp      a,MAXSEC+1
        jr      c,bot0          ; repeat til sector > MAXSEC
        jp      BOOTE




bsywat: ; Wait while controller is busy
        ;
        ; Entry:   nil
        ; Exit:    nil
        ; Altered: A
        ;
        ex      (sp),hl         ; delay for FDC to set busy status
        ex      (sp),hl
        ex      (sp),hl
        ex      (sp),hl
bsyw0:  in      a,(FDCSR)       ; read controller status
        rra                     ; CY := bsy bit
        jr      c,bsyw0         ; loop while busy
        ret


        end     boot